**3.15. Даты запрета изменения**

Подсистема «Даты запрета изменения» позволяет заблокировать изменения любых данных информационной базы (документов, записей регистров, элементов справочников и др.) ранее определенной даты. Администратор системы может настроить как одну общую дату для всей информационной базы в целом, так и несколько дат по разделам и/или отдельным объектам разделов учета.

Подсистема всегда предоставляет возможность настройки дат запрета, как для всех пользователей, так и для конкретных пользователей, групп пользователей (опционально – для внешних пользователей, групп внешних пользователей).

Интерфейс настройки разработан от минимальных возможностей «нет запрета» до максимальных возможностей, определенных при внедрении, но не более чем По разделам и объектам в сочетании с настройкой По пользователям (и группам пользователей).

Подсистема позволяет устанавливать как произвольные даты запрета, так и относительные даты запрета (конец прошлого месяца, конец прошлого квартала и другие).

**Настройка**

1. [Определить состав типов, для которых будет выполняться запрет изменения данных](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_состав_типов,).

2. [Определить состав типов, для которых будут настраиваться запреты загрузки данных](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_состав_типов,_1).

3. [Определить максимальные возможности настройки дат запрета (общая дата, по разделам, по объектам, по разделам и объектам)](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_максимальные_возможности).

4. [Определить поля объектов метаданных, которые будут использованы для получения проверяемых данных (даты, раздела, объекта)](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_поля_объектов).

5. [Определить случаи условного отказа от проверки запрета изменения и определить случаи проверки запрета загрузки](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_случаи_условного).

6. [Определить возможность настройки дат запрета для внешних пользователей и групп внешних пользователей](https://its.1c.ru/db/content/bsp301doc/src/3.15.%20%D0%B4%D0%B0%D1%82%D1%8B%20%D0%B7%D0%B0%D0%BF%D1%80%D0%B5%D1%82%D0%B0%20%D0%B8%D0%B7%D0%BC%D0%B5%D0%BD%D0%B5%D0%BD%D0%B8%D1%8F.htm?_=1542292879#_определить_возможность_настройки).

**Определить состав типов, для которых будет выполняться запрет изменения данных**

Определить состав типов справочников, документов, регистров, для которых будет выполняться запрет изменения данных.

Создать подписки на события и указать в них выбранные типы согласно таблице, приведенной ниже.

Подписки на событие ПередЗаписью для проверки запрета изменения данных:

Таблица 3.28.

|  |  |  |
| --- | --- | --- |
| Имя | Источник | Обработчик |
| ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента | Элементы типа: ДокументОбъект | ДатыЗапретаИзменения.ПроверитьДатуЗапретаИзмененияПередЗаписьюДокумента |
| ПроверитьДатуЗапретаИзмененияПередЗаписью | Элементы типов: СправочникОбъект, ПланВидовХарактеристикОбъект, ПланСчетовОбъект, ПланВидовРасчетаОбъект, БизнесПроцессОбъект, ЗадачаОбъект, ПланОбменаОбъект | ДатыЗапретаИзменения. ПроверитьДатуЗапретаИзмененияПередЗаписью |
| ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписей | Элементы типов: РегистрСведенийНаборЗаписей, РегистрНакопленияНаборЗаписей | ДатыЗапретаИзменения. ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписей |
| ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписейРегистраБухгалтерии | Элементы типа: РегистрБухгалтерииНаборЗаписей | ДатыЗапретаИзменения. ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписейРегистраБухгалтерии |
| ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписейРегистраРасчета | Элементы типа: РегистрРасчетаНаборЗаписей | ДатыЗапретаИзменения. ПроверитьДатуЗапретаИзмененияПередЗаписьюНабораЗаписейРегистраРасчета |

Подписки на событие ПередУдалением для проверки запрета изменения данных:

Таблица 3.29.

|  |  |  |
| --- | --- | --- |
| Имя | Источник | Обработчик |
| ПроверитьДатуЗапретаИзмененияПередУдалением | Элементы типа: СправочникОбъект, ДокументОбъект, ПланВидовХарактеристикОбъект, ПланСчетовОбъект, ПланВидовРасчетаОбъект, БизнесПроцессОбъект, ЗадачаОбъект, ПланОбменаОбъект | ДатыЗапретаИзменения. ПроверитьДатуЗапретаИзмененияПередУдалением |

Для выбранных объектов метаданных необходимо вставить в модуль формы объекта в процедуру обработчика события ПриЧтенииНаСервере вызов:

ДатыЗапретаИзменения.ОбъектПриЧтенииНаСервере(ЭтотОбъект, ТекущийОбъект).

При выполнении вызова будет выполнена проверка запрета изменения, и при наличии запрета свойство формы ТолькоПросмотр будет установлено Истина.

**Определить состав типов, для которых будут настраиваться запреты загрузки данных**

Для запрета загрузки данных по узлам планов обмена необходимо в определяемый тип АдресатЗапретаИзменения добавить типы требуемых планов обмена. Если хотя бы один тип плана обмена добавлен в состав определяемого типа АдресатЗапретаИзменения, то по команде Даты запрета загрузки данных будет открыта форма Даты запрета изменения данных в режиме редактирования дат запрета загрузки.

**Определить максимальные возможности настройки дат запрета (общая дата, по разделам, по объектам, по разделам и объектам)**

Для различных прикладных решений требования к настройке даты запрета сильно отличаются. Для простой однопользовательской конфигурации достаточно одной общей даты, а для корпоративного решения требуется множество разрезов дат запрета к различным областям планирования и учета. Для этих целей предусмотрены разделы – это разрезы областей планирования и учета для установки дат запрета. Например, Складской учет, Бухгалтерская отчетность, Планирование. В подсистеме разделы – это элементы объекта метаданных ПланВидовХарактеристик.РазделыДатЗапретаИзменения, которые создаются автоматически на основе описания разделов в процедуре ПриЗаполненииРазделовДатЗапретаИзменения общего модуля ДатыЗапретаИзмененияПереопределяемый (режиме 1С:Предприятие элементы не редактируются).

При необходимости разделы могут быть уточнены объектом – например, раздел Складской учет можно уточнить складом. Для этого разделу нужно установить тип, например СправочникСсылка.Склады.

Возможны четыре варианта внедрения:

1. Общая дата. В этом варианте список разделов пуст, у пользователя будет возможность задавать общую дату на всю конфигурацию (для всех пользователей или по пользователям).

2. По разделам. В этом варианте список разделов состоит из двух и более разделов, типы разделов не определены (ПланВидовХарактеристикСсылка.РазделыДатЗапретаИзменения). В интерфейсе объекты не отображаются, их нельзя добавить. Например, разделы Учет и Планирование. При этом можно задать общую дату или две даты отдельно по каждому разделу.

3. По объектам. В этом варианте список разделов состоит из одного раздела. Этот раздел не отображается в интерфейсе, но используется при получении данных для проверки. У раздела задан непустой тип объектов. Например, раздел Бухгалтерский учет с типом СправочникСсылка.Организации. При этом можно задать общую дату или даты по отдельным организациям.

4. По разделам и объектам. В этом самом общем варианте список разделов состоит из двух и более разделов, причем хотя бы один раздел должен иметь тип объектов. Например, Учет по организациям и Планирование.

// Заполняет разделы дат запрета изменения, используемые при настройке дат запрета.

// Если не указать ни одного раздела, тогда будет доступна только настройка общей даты запрета.

//

// Параметры:

//  Разделы - ТаблицаЗначений - с колонками:

//   \* Имя - Строка - имя используемое в описании источников данных в

//       процедуре ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения.

//

//   \* Идентификатор - УникальныйИдентификатор - идентификатор ссылки элемента плана видов характеристик.

//       Чтобы получить идентификатор нужно в режиме 1С:Предприятия выполнить метод платформы:

//       "ПланыВидовХарактеристик.РазделыДатЗапретаИзменения.ПолучитьСсылку().УникальныйИдентификатор()".

//       Не следует указывать идентификаторы, полученные любым другим способом,

//       так как это может нарушить их уникальность.

//

//   \* Представление - Строка - представляет раздел в форме настройки дат запрета.

//

//   \* ТипыОбъектов  - Массив - типы ссылок объектов в разрезе которых можно настроить даты запрета,

//       например, Тип("СправочникСсылка.Организации"), если не указано ни одного типа,

//       то даты запрета будут настраиваться только с точностью до раздела.

//

Процедура ПриЗаполненииРазделовДатЗапретаИзменения(Разделы) Экспорт

Раздел = Разделы.Добавить();

Раздел.Имя  = "\_ДемоБанк";

Раздел.Идентификатор = Новый УникальныйИдентификатор("4109a54a-f3ea-474c-9079-be08bf335668");

Раздел.Представление = НСтр("ru = 'Демо: Банк'");

Раздел.ТипыОбъектов.Добавить(Тип("СправочникСсылка.\_ДемоБанковскиеСчета"));

Раздел = Разделы.Добавить();

Раздел.Имя  = "\_ДемоНачислениеЗарплаты";

Раздел.Идентификатор = Новый УникальныйИдентификатор("100aba96-ea50-4f82-a06c-2e3fdc39a9f1");

Раздел.Представление = НСтр("ru = 'Демо: Начисление зарплаты'");

КонецПроцедуры

**Определить поля объектов метаданных, которые будут использованы для получения проверяемых данных (даты, раздела, объекта)**

Для подготовки данных к проверке на запрет изменения требуется для каждого из выбранных объектов метаданных определить поля – источники значений. Для этих целей используется процедура ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения переопределяемого модуля.

// Содержит описание таблиц и полей объектов для проверки запретов изменения данных.

//   Вызывается из процедуры ИзменениеЗапрещено общего модуля ДатыЗапретаИзменения,

//   используемой в подписке на событие ПередЗаписью объекта для проверки наличия

//   запретов и отказа от изменений запрещенного объекта.

//

// Параметры:

//  ИсточникиДанных - ТаблицаЗначений - с колонками:

//   \* Таблица     - Строка - полное имя объекта метаданных,

//                   например Метаданные.Документы.ПриходнаяНакладная.ПолноеИмя().

//   \* ПолеДаты    - Строка - имя реквизита объекта или табличной части,

//                   например, "Дата", "Товары.ДатаОтгрузки".

//   \* Раздел      - Строка - имяраздела дат запрета, указанного в

//                   процедуре ПриЗаполненииРазделовДатЗапретаИзменения (см. выше).

//   \* ПолеОбъекта - Строка - имя реквизита объекта или реквизита табличной части,

//                   например, "Организация", "Товары.Склад".

//

//  Для добавления строки имеется процедура ДобавитьСтроку в общем модуле ДатыЗапретаИзменения.

//

Процедура ЗаполнитьИсточникиДанныхДляПроверкиЗапретаИзменения(ИсточникиДанных) Экспорт

ДатыЗапретаИзменения.ДобавитьСтроку(ИсточникиДанных,

Метаданные.Документы.\_ДемоОприходованиеТоваров.ПолноеИмя(),

"Дата", "\_ДемоСкладскойУчет", "МестоХранения");

ДатыЗапретаИзменения.ДобавитьСтроку(ИсточникиДанных,

Метаданные.Документы.\_ДемоСписаниеТоваров.ПолноеИмя(),

"Дата", "\_ДемоСкладскойУчет", "МестоХранения");

ДатыЗапретаИзменения.ДобавитьСтроку(ИсточникиДанных,

Метаданные.Документы.\_ДемоСписаниеБезналичныхДенежныхСредств.ПолноеИмя(),

"ДатаПроведенияБанком", "\_ДемоБанк", "БанковскийСчет");

КонецПроцедуры

Поле может быть задано «через точку», например, если в документе указана ссылка на документ-основание, содержащий объект. Тогда реквизит будет задан так: ДокументОснование.Склад, где ДокументОснование – реквизит документа, проверяемого на запрет изменения. Можно указать поле «через несколько точек».

В качестве поля можно указать поле табличной части, в этом случае используется тот же метод «через точку», например Товары.Склад. Указывать поле табличной части можно только в проверяемом документе, а не в документе-основании (такое описание не поддерживается).

Следует иметь в виду, что использование метода «через точку» потребует дополнительного обращения к базе данных для получения значения, а использование поля табличной части увеличит количество проверяемых данных.

Для объекта данных может потребоваться несколько проверок (например, для документа ПеремещениеТоваров требуется проверить запрет изменения по двум складам). В этом случае используются несколько строк для описания проверок по одному объекту метаданных (см. пример выше).

**Определить случаи условного отказа от проверки запрета изменения и определить случаи проверки запрета загрузки**

Кроме стандартного случая отказа от проверки запрета изменения и запрета загрузки данных при обновлении информационной базы, прикладной разработчик может пропустить проверку запретов по прикладным причинам.

Если в прикладной конфигурации потребовалось пропустить проверку запрета изменения данных, например, если заказ не закрыт (или при особых случаях обмена данными пропустить проверку запрета загрузки данных) следует воспользоваться переопределяемой процедурой ПередПроверкойЗапретаИзменения.

// Позволяет переопределить выполнение проверок запретов по произвольному условию.

//

// Параметры:

//  Объект       - СправочникОбъект,

//                 ДокументОбъект,

//                 ПланВидовХарактеристикОбъект,

//                 ПланСчетовОбъект,

//                 ПланВидовРасчетаОбъект,

//                 БизнесПроцессОбъект,

//                 ЗадачаОбъект,

//                 ПланОбменаОбъект - объект данных (ПередЗаписью или ПриЧтенииНаСервере).

//               - РегистрСведенийНаборЗаписей,

//                 РегистрНакопленияНаборЗаписей,

//                 РегистрБухгалтерииНаборЗаписей,

//                 РегистрРасчетаНаборЗаписей - набор записей (ПередЗаписью или ПриЧтенииНаСервере).

//

//  ПроверкаЗапретаИзменения    - Булево - когда Истина, тогда проверка изменения выполняется.

//                                Если установить Ложь, тогда проверка запрета изменения будет пропущена.

//

//  УзелПроверкиЗапретаЗагрузки - Неопределено - проверка запрета загрузки не выполняется.

//                              - ПланыОбменаСсылка - проверка запрета загрузки выполняется. Если

//                                установить Неопределено, проверка запрета загрузки будет пропущена.

//

//  ВерсияОбъекта               - Строка - начальное значение "". Проверяются обе версии объекта.

//                                Если установить "СтараяВерсия" или "НоваяВерсия", тогда будет

//                                выполнена проверка только старой или только новой версии объекта.

//

Процедура ПередПроверкойЗапретаИзменения(Объект,

                                         ПроверкаЗапретаИзменения,

                                         УзелПроверкиЗапретаЗагрузки,

                                         ВерсияОбъекта) Экспорт

Если ТипЗнч(Объект) = Тип("ДокументОбъект.\_ДемоЗаказПокупателя") Тогда

СтатусЗаказа = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(Объект.Ссылка, "СтатусЗаказа");

ЗаказЗакрытСтараяВерсия = (СтатусЗаказа        = Перечисления.\_ДемоСтатусыЗаказовПокупателей.Закрыт);

ЗаказЗакрытНоваяВерсия  = (Объект.СтатусЗаказа = Перечисления.\_ДемоСтатусыЗаказовПокупателей.Закрыт);

Если Не ЗаказЗакрытСтараяВерсия И Не ЗаказЗакрытНоваяВерсия Тогда

ПроверкаЗапретаИзменения = Ложь;

УзелПроверкиЗапретаЗагрузки = Неопределено;

ИначеЕсли Не ЗаказЗакрытНоваяВерсия Тогда

ВерсияОбъекта = "СтараяВерсия"; // Проверить только старую версию объекта.

ИначеЕсли Не ЗаказЗакрытСтараяВерсия Тогда

ВерсияОбъекта = "НоваяВерсия"; // Проверить только новую версию объекта.

КонецЕсли;

ИначеЕсли ТипЗнч(Объект) = Тип("ДокументОбъект.\_ДемоСписаниеБезналичныхДенежныхСредств") Тогда

// Отказ от проверки с учетом того, что ДатаПроведенияБанком, используемая в проверке не указывается,

// если документ не проведен банком, а указывается позже после проведения документа банком.

ПроведеноБанкомНоваяВерсия  = Объект.ПроведеноБанком;

ПроведеноБанкомСтараяВерсия = ОбщегоНазначения.ЗначениеРеквизитаОбъекта(

Объект.Ссылка, "ПроведеноБанком") = Истина;

Если Не ПроведеноБанкомНоваяВерсия И Не ПроведеноБанкомСтараяВерсия Тогда

ПроверкаЗапретаИзменения = Ложь;

УзелПроверкиЗапретаЗагрузки = Неопределено;

ИначеЕсли Не ПроведеноБанкомНоваяВерсия Тогда

ВерсияОбъекта = "СтараяВерсия"; // Проверить только старую версию объекта.

ИначеЕсли Не ПроведеноБанкомСтараяВерсия Тогда

ВерсияОбъекта = "НоваяВерсия"; // Проверить только новую версию объекта.

КонецЕсли;

КонецЕсли;

КонецПроцедуры

**Определить возможность настройки дат запрета для внешних пользователей и групп внешних пользователей**

Если в прикладном решении требуется делать настройку по внешним пользователям и группам внешних пользователей, то нужно вписать код в процедуру НастройкаИнтерфейса переопределяемого модуля:

Процедура НастройкаИнтерфейса(Знач НастройкиРаботыИнтерфейса) Экспорт

НастройкиРаботыИнтерфейса.ИспользоватьВнешнихПользователей = Истина;

КонецПроцедуры

**Размещение в командном интерфейсе**

Если в конфигурации не используется подсистема «Настройки программы», необходимо разместить в командном интерфейсе ответственного за даты запрета объекты метаданных:

● команду ДатыЗапретаИзмененияДанных – для просмотра и редактирования дат запрета изменения;

● команду ДатыЗапретаЗагрузкиДанных – для просмотра и редактирования дат запрета загрузки (если запреты загрузки не используются, команду размещать не требуется).

Для размещения команд требуется включить регистр сведений ДатыЗапретаИзменения в подсистему интерфейса (у регистра отключено использование стандартных команд).

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы «Даты запрета изменения» следует использовать роли:

Таблица 3.30.

| № | Роли и их назначение |
| --- | --- |
| 1. | ПолныеПрава (из подсистемы «Базовая функциональность»)  Просмотр и редактирование дат запрета изменения и дат запрета загрузки (доступ к форме Даты запрета изменения данных с отчетами) |
| 2. | Добавление изменение дат запрета изменения  Просмотр и редактирование дат запрета изменения (доступ к форме Даты запрета изменения данных и отчету Даты запрета изменения данных) |

**Использование при разработке конфигурации**

При создании новых прикладных объектов метаданных нужно повторно выполнять соответствующую часть процедуры настройки, описанной выше.

Для дополнительной проверки запрета изменения (вне подписок на события) используется функция ИзменениеЗапрещено модуля ДатыЗапретаИзменения.

Также может потребоваться выполнить программную проверку запрета изменения нестандартного вида. Для этого предусмотрена функция НайденЗапретИзмененияДанных модуля ДатыЗапретаИзменения, которая выполнит проверку и вернет ее результат, а также отправит стандартное сообщение пользователю об ошибке.

Для работы функции нужно подготовить данные, шаблон которых легко получить (см. комментарий функции). Эта функция используется в подписке на событие перед записью. Данные, полученные из объекта данных, передаются в функцию дважды – для старого и нового экземпляров объекта.

// Выполняет поиск дат запрета по проверяемым данным

// для авторизованного пользователя или узла плана обмена.

//

// Параметры:

//  ДанныеДляПроверки - ТаблицаЗначений - возвращается функцией ШаблонДанныхДляПроверки

//                      общего модуля ДатыЗапретаИзменения.

//

//  ОписаниеДанных    - Неопределено - текст сообщения о запрете не формируется.

//                    - Структура - со свойствами:

//                      \* НоваяВерсия - Булево - если Истина, то сообщение о запрете

//                                   формировать для новой версии, иначе для старой версии.

//                      \* Данные - Ссылка,Объект - ссылка или объект данных для получения

//                                   представления, которое будет использовано в сообщении о запрете.

//                               - НаборЗаписей - набор записей регистра для получения

//                                   представления, которое будет использовано в сообщении о запрете.

//                               - Структура - со свойствами для сообщения о запрете:

//                                   \* Регистр - Строка - полное имя регистра;

//                                   \* Отбор   - Отбор - отбор набора записей.

//                               - Строка - подготовленное представление данных,

//                                 которое будет использовано в сообщении о запрете.

//

//  ОписаниеОшибки    - Строка - (возвращаемое значение) описание запрета изменения или загрузки.

//                      Не заполняется, если параметр ОписаниеДанных не указан.

//                    - Null - в этом случае текст сообщения об ошибке не будет подготовлен,

//                      что ускоряет выполнение проверки, когда запрет найден.

//

//  УзелПроверкиЗапретаЗагрузки - Неопределено - выполнить проверку изменения данных.

//                              - ПланыОбменаСсылка.<Имя плана обмена> - выполнить проверку

//                                загрузки данных для указанного узла.

//

// Возвращаемое значение:

//  Булево - если Истина, значит найден хотя бы один запрет изменения.

//

Функция НайденЗапретИзмененияДанных(Знач ДанныеДляПроверки,

                                    ОписаниеДанных = Неопределено,

                                    ОписаниеОшибки = Null,

                                    УзелПроверкиЗапретаЗагрузки = Неопределено) Экспорт

**Взаимодействие при обмене данными**

Для проверки запрета загрузки следует использовать функцию ЗагрузкаЗапрещена модуля ДатыЗапретаИзменения.

Если при обмене данными требуется выполнить запись, когда признак ОбменДанными.Загрузка не установлен, но без проверки запрета изменения, то в свойства объекта ДополнительныеСвойства нужно вставить свойство ПропуститьПроверкуЗапретаИзменения.

**Настройка обмена данными**

Для настройки обмена данными следует руководствоваться общими правилами.

В планы обмена распределенной информационной базы (РИБ) рекомендуется включать все объекты метаданных подсистемы, кроме константы ВерсияДатЗапретаИзменения и плана видов характеристик РазделыДатЗапретаИзменения.

Из остальных планов обмена (не РИБ) рекомендуется исключать все объекты метаданных подсистемы.